anope-services/PKGBUILD

# Maintainer: Jack L. Frost <fbt@fleshless.org>

#pkgbase=
pkgname=anope-services
pkgver=2.0.3
pkgrel=1
pkgdesc='A set of IRC Services designed for flexibility and ease of use'
url='http://anope.org'
arch=( 'x86_64' 'i686' )
license=( 'GPL' )
makedepends=( 'cmake' )
install=anope-services.install

source=(
	"https://github.com/anope/anope/releases/download/${pkgver}/anope-${pkgver}-source.tar.gz"
	'anope-services.install'
)

build() {
	cd "anope-${pkgver}-source"
	
	# Non-interactive config
	cat <<- EOF > config.cache
		INSTDIR="$srcdir/anope-services"
		RUNGROUP="anope"
		UMASK=077
		DEBUG="no"
		USE_RUN_CC_PL="no"
		USE_PCH="no"
		EXTRA_INCLUDE_DIRS=""
		EXTRA_LIB_DIRS=""
		EXTRA_CONFIG_ARGS=""
	EOF

	./Config -nointro -quick

	cd build
	make
	make install
}

package() {
	cd "${srcdir}/anope-services"

	# Create directories
	install -Dd "${pkgdir}"{/var/log,/var/lib,/etc,/usr/lib}/${pkgname}
	install -Dd "${pkgdir}/var/lib/${pkgname}/runtime"
	install -Dd "${pkgdir}/usr/bin"
	install -Dd "${pkgdir}/usr/lib/${pkgname}"/{modules,locale}

	# Copy files

	# Executable files
	install -Dm755 bin/{anopesmtp,services} "${pkgdir}/usr/bin"

	# Configuration files
	install -Dm644 conf/*.conf "${pkgdir}/etc/${pkgname}"

	# Loadable modules
	install -Dm644 lib/modules/* "${pkgdir}/usr/lib/${pkgname}/modules"

	cp -r data/* "${pkgdir}/var/lib/${pkgname}"
	cp -r locale/* "${pkgdir}/usr/lib/${pkgname}/locale"
}

sha1sums=('dca45d491a04bff18359f0973e89e181c67c6640'
          '884af887bf5cde2f74f8edb38fabed3e616b6535')