pkgname=graphicsmagick-webp
pkgver=1.3.35
pkgrel=1
pkgdesc='Image processing system'
url='http://www.graphicsmagick.org/'
arch=('i686' 'x86_64')
license=('MIT')
optdepends=('jasper: jp2 module'
            'libpng: png module'
            'libwmf: wmf module'
            'libxml2: msl, svg, url modules'
            'libtiff: ps2, ps3, tiff modules'
            'ghostscript: pdf, ps modules')
makedepends=('perl' 'jasper' 'libpng' 'libwmf' 'libxml2' 'libtiff' 'libwebp')
depends=('freetype2' 'libxext' 'libsm' 'lcms2' 'libltdl' 'bzip2' 'xz')
source=("GraphicsMagick-${pkgver}.tar.xz")

conflicts=( 'graphicsmagick' )

options=('!emptydirs' 'libtool')

build() {
	cd "${srcdir}/GraphicsMagick-${pkgver}"
	./configure \
		--prefix=/usr \
		--enable-shared \
		--with-modules \
		--with-perl \
		--with-gs-font-dir=/usr/share/fonts/Type1 \
		--with-quantum-depth=16 \
		--with-threads
	make
}

package() {
	cd "${srcdir}/GraphicsMagick-${pkgver}"

	make DESTDIR="${pkgdir}" install

	# Install MIT license
	install -Dm644 "Copyright.txt" "${pkgdir}/usr/share/licenses/${pkgname}/Copyright.txt"

	# Install perl bindings
	# The patching was introduced in order to build perl module without installing package itself and
	# not to introduce unnecessary path into LD_RUN_PATH
	cd PerlMagick
	sed -i -e "s:'LDDLFLAGS'  => \"\(.*\)\":'LDDLFLAGS'  => \"-L${pkgdir}/usr/lib \1\":" Makefile.PL
	perl Makefile.PL INSTALLDIRS=vendor PREFIX=/usr DESTDIR="${pkgdir}"
	sed -i -e "s/LDLOADLIBS =/LDLOADLIBS = -lGraphicsMagick/" Makefile
	make
	make install

	# Remove perllocal.pod and .packlist
	rm -rf "${pkgdir}/usr/lib/perl5/core_perl"
	rm "${pkgdir}/usr/lib/perl5"/*/"vendor_perl/auto/Graphics/Magick/.packlist"
}

sha1sums=('b0460d7fb8b2d542a44446322ea62c053bc54b0c')