ircd-ratbox/PKGBUILD

# Author: Kevin MacMartin <prurigro@gmail.com>
# Imported for use on https://code.fleshless.org

pkgname=ircd-ratbox
pkgver=3.0.10
pkgrel=3
pkgdesc='An advanced, stable and fast ircd'
url='http://www.ratbox.org'
license=('GPL')
depends=('openssl' 'sqlite' 'libtool')
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h')
backup=("etc/$pkgname/ircd.motd")
install="$pkgname.install"

source=(
	"http://www.ratbox.org/download/$pkgname-$pkgver.tar.bz2"
	"$pkgname.service"
	"$pkgname.conf"
)

build() {
	cd "$pkgname-$pkgver"

	./configure --prefix="/usr/share/$pkgname" \
		--with-confdir="/etc/$pkgname" \
		--with-logdir="/var/log/$pkgname" \
		--bindir=/usr/bin

	make
	cd contrib
	make
}

package() {
	install -d "$pkgdir/etc/$pkgname"
	install -Dm644 $pkgname.service "$pkgdir/usr/lib/systemd/system/$pkgname.service"
	install -Dm644 $pkgname.conf "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
	cd $pkgname-$pkgver
	make DESTDIR="$pkgdir" install
	install -d "$pkgdir/usr/share/$pkgname/modules/contrib/"
	cp contrib/.libs/*.so "$pkgdir/usr/share/$pkgname/modules/contrib/"
}

sha1sums=('fa1645495c765cf921726b65172ff5eceeea008a'
          '84fb85e7c8b858e8e11be11e8abe60e3cada3c80'
          '3dd5270ced5243adf4dde43ef11c3a0a68001240')