# Maintainer: Jack L. Frost <fbt@fleshless.org>
# AUR Maintainer: Slash <demodevil5[at]yahoo[dot]com>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk> with contributions from Andreas Schweitzer <sig11@gmx.net>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=qstat
pkgver=2.14
pkgrel=1
pkgdesc="A command line utility that displays the status of internet game servers"
url="http://www.qstat.org/"
arch=('i686' 'x86_64')
license=('custom:Artistic')
depends=('glibc')
conflicts=('qstat-cvs' 'qstat-svn')
backup=('etc/qstat.cfg')
source=( "https://github.com/multiplay/qstat/archive/v${pkgver}.tar.gz" )

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	sed "s#strndup#strndupxyz#g" -i qstat.c

	./autogen.sh
	./configure --prefix=/usr --sysconfdir=/etc
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	make DESTDIR="${pkgdir}" install

	# Install License
	install -D -m 0644 LICENSE.txt \
		"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}

sha1sums=('6b18671939ba8a0afc9669e0e4069e4ef9d02a0e')