sx-utils/PKGBUILD

# Maintainer: Jack L. Frost <fbt@fleshless.org>

pkgbase='sx-utils'
pkgname=( 'sx-utils' 'sx-utils-xdg-compat' )
pkgver='1.6.4'
pkgrel='1'
pkgdesc='An incomplete set of tools to replace xdg-utils'
url='https://code.fleshless.org/fbt/sx-open'
arch=( 'x86_64' 'i686' )
license=( 'ISC' )
depends=( 'bash' )
replaces=( 'sx-open' )

source=( "https://code.fleshless.org/fbt/sx-open/archive/${pkgver}.tar.gz" )

_xdg_utils_shim=(
	xdg-{desktop-icon,desktop-menu,email,icon-resource,mime,screensaver,settings}
)

package_sx-utils() {
	optdepends=( 'sx-utils-xdg-compat: symbolic links for xdg -> sx' )

	cd "sx-open-${pkgver}"

	install -Dm755 sx-open "$pkgdir/usr/bin/sx-open"
}

package_sx-utils-xdg-compat() {
	depends=( 'fake' )
	provides=( 'xdg-utils' )
	conflicts=( 'xdg-utils' )

	cd "sx-open-${pkgver}"

	mkdir -pm755 "$pkgdir/usr/bin"
	ln -s sx-open "$pkgdir/usr/bin/xdg-open"

	for x in "${_xdg_utils_shim[@]}"; do
		ln -s fake "$pkgdir/usr/bin/$x"
	done
}

sha1sums=('47bdb1b2ad17f4af3b980cabb70b2f4b6ba6a41c')