# Maintainer: Jack L. Frost <fbt@fleshless.org>

_srcname='ubase'
pkgbase=ubase-extras
pkgname=( halt-ubase-git killall5-ubase-git  )
pkgver=r599.e3dacbb
pkgrel=1
pkgdesc="A few tools from suckless.org's ubase packaged for Spark."
url='http://core.suckless.org/ubase'
arch=( 'x86_64' 'i686' )
license=( 'MIT' )

source=( "git://git.suckless.org/ubase" )
sha1sums=( 'SKIP' )

pkgver() {
	cd "${_srcname}"

	if git_version=$( git describe --long --tags 2>/dev/null ); then
		IFS='-' read last_tag tag_rev commit <<< "$git_version"
		printf '%s.r%s.%s' "$last_tag" "$tag_rev" "$commit"
	else
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	fi
}

build() {
	cd "${_srcname}"
	make halt killall5
}

package_halt-ubase-git() {
	cd "${_srcname}"

	mkdir -pm755 "$pkgdir/usr/bin"
	cp halt "$pkgdir/usr/bin/halt"

	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_killall5-ubase-git() {
	cd "${_srcname}"

	mkdir -pm755 "$pkgdir/usr/bin"
	cp killall5 "$pkgdir/usr/bin/killall5"

	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}